Posts with «processing.org» label

Jumper: Arduino controlled animation

In this project, I have connected an Arduino to my computer and used a photoresistor to control an animation on the screen. Other sensors could have been used, but I chose a photoresistor because it feels like magic!!

The photoresistor responds to changes in ambient light as my hand moves up and down. The Arduino sends the reading to a Processing sketch on the computer via a Serial command (through the USB cable). The processing sketch interprets the signal from the Arduino and selects the appropriate picture to display.

I took a series of screenshots from the following YouTube video: http://www.youtube.com/watch?v=h6nE8m74kDg And after borrowing a bit of code from these sites (1,2), the project was born.
This idea is not new, nor my own. There are many people who have done this project before, but I thought to blog about how I have done it, just for fun.

The Project Movie

Components Required

Arduino Uno (and associated software), and USB cable
Photoresistor or Photocell
10K resistor
Wires to put it all together
Processing IDE from http://processing.org
Computer/laptop

The Arduino Sketch

The picture above was made using Fritzing

The Arduino Code:

You can download the Arduino IDE from this site.

/* Jumper: Using an Arduino to animate:
   Written by ScottC on 02/06/2012 */

int photoRPin = 0; 
int minLight;
int maxLight;
int lightLevel;
int adjustedLightLevel;
int oldLightLevel;

void setup() {
  Serial.begin(9600);
  
  //Setup the starting light level limits
  lightLevel=analogRead(photoRPin);
  minLight=lightLevel-10;
  maxLight=lightLevel;
  oldLightLevel=lightLevel;
}

void loop(){
   lightLevel=analogRead(photoRPin);
   delay(10);
  
  //auto-adjust the minimum and maximum limits in real time   
   if(minLight>lightLevel){
     minLight=lightLevel;
   }
   if(maxLight<lightLevel){
     maxLight=lightLevel;
   }
   
   //Map the light level to produce a result between 1 and 28.
   adjustedLightLevel = map(lightLevel, (minLight+20), (maxLight-20), 1, 28); 
   adjustedLightLevel = constrain (adjustedLightLevel, 1,28);
   
   /*Only send a new value to the Serial Port if the 
     adjustedLightLevel value changes.*/
   if(oldLightLevel==adjustedLightLevel){
     //do nothing if the old value and the new value are the same.
   }else{
     //Update the oldLightLevel value for the next round
     oldLightLevel=adjustedLightLevel;
     
     /*Send the adjusted Light level result 
       to Serial port (processing)*/
     Serial.println(adjustedLightLevel);
   } 
}

The code above was formatted using this site.

The Processing Code:

You can download the Processing IDE from this site.

/* Jumper: Using an Arduino to animate
   Written by ScottC on 02/06/2012

Source code derived from : 
  http://processing.org/learning/topics/sequential.html
  http://processing.org/discourse/beta/num_1267080062.html

Pictures captured from:
  http://www.youtube.com/watch?v=h6nE8m74kDg      
  
======================================================= */

import processing.serial.*;
Serial myPort;
String sensorReading="";

// Create the array that will hold the images
PImage[] movieImage = new PImage[29];

/* The frame variable is  used to control which 
   image is displayed */
int frame = 1;



/* Setup the size of the window. Initialise serial communication with Arduino
   and pre-load the images to be displayed later on. This is done only once.
   I am using COM6 on my computer, you may need replace this value with your
   active COM port being used by the Arduino.*/

void setup(){
  size(700,600);
  
  myPort = new Serial(this, "COM6", 9600);
  myPort.bufferUntil('\n');
  
  for(int i=0;i<28;i++){
    movieImage[i] = loadImage("Jumper" + (i+1) + ".jpg");
  }
}




// The draw function controls the animation sequence.

void draw(){
  
  //this draws the relevant image to the window  
  image(movieImage[frame-1],0,0,width,height);
}

void serialEvent (Serial myPort){
 sensorReading = myPort.readStringUntil('\n');
  if(sensorReading != null){
    sensorReading=trim(sensorReading);
    if (sensorReading.length()<2){
      frame = integerFromChar(sensorReading.charAt(0));
    }else{
      frame = integerFromChar(sensorReading.charAt(0))*10;
      frame += integerFromChar(sensorReading.charAt(1));
    }
  }
}



/* This function used to convert the character received from the
   serial port (Arduino), and converts it to a number */
   
int integerFromChar(char myChar) {
  if (myChar < '0' || myChar > '9') {
    return -1;
  }else{
  return myChar - '0';
  }
}

The code above was formatted using this site.

The pictures

Captured from this YouTube Video: http://www.youtube.com/watch?v=h6nE8m74kDg

Neural Network (Part 7) : Cut and Paste Code

Ok - so you don't like tutorials, and would rather just cut and paste some code.
This is for you.
http://www.openprocessing.org/visuals/?visualID=33991

Make sure to select "Source code" when you get there, otherwise it will be quite boring.
Here is an animated gif which shows the program in action.

See BELOW for the WHOLE screenshot so that you don't have to speed read.

If you want to know how it works, then you will have to go back and read part 1 to 6.

Neural Network

But as you can see from the example above:
Before the neural network is trained, the outputs are not even close to the expected outputs. After training, the neural network produces the desired results (or very close to it).

Please note, this neural network also allows more than one output neuron, so you are not limited to single yes no decisions. You can use this neural network to make classifications. You will soon see this with my LED colour sensor.

Feel free to use this Neural Network in your own projects, but please let me know if you do, just for curiosity sake.

Update: See below for the Processing Sketch (much easier than going to the open processing site). It is a bit long - but saves you from having to navigate to another site.

Processing sketch

/*Neural Network created by ScottC on 15th Aug 2011
 
Please visit my blog for a detailed explanation of my Neural Network
http://arduinobasics.blogspot.com/p/arduinoprojects.html
 
*/
   
   
 
void setup(){
  ArrayList myTrainingInputs = new ArrayList();
  ArrayList myTrainingOutputs = new ArrayList();
   
  float[] myInputsA={0,0};
  float[] myInputsB={0,1};
  float[] myInputsC={1,0};
  float[] myInputsD={1,1};
  float[] myOutputsA={1};
  float[] myOutputsB={0};
   
   
  println("TRAINING DATA");
  println("--------------------------------------------");
  myTrainingInputs.add(myInputsA);
  myTrainingOutputs.add(myOutputsA);
  println("INPUTS= " + myInputsA[0] + ", " + myInputsA[1] + "; Expected output = " + myOutputsA[0]);
  myTrainingInputs.add(myInputsB);
  myTrainingOutputs.add(myOutputsB);
  println("INPUTS= " + myInputsB[0] + ", " + myInputsB[1] + "; Expected output = " + myOutputsB[0]);
  myTrainingInputs.add(myInputsC);
  myTrainingOutputs.add(myOutputsB);
  println("INPUTS= " + myInputsC[0] + ", " + myInputsC[1] + "; Expected output = " + myOutputsB[0]);
  myTrainingInputs.add(myInputsD);
  myTrainingOutputs.add(myOutputsA);
  println("INPUTS= " + myInputsD[0] + ", " + myInputsD[1] + "; Expected output = " + myOutputsA[0]);
  println("--------------------------------------------");
  
  NeuralNetwork NN = new NeuralNetwork();
  NN.addLayer(2,2);
  NN.addLayer(2,1);
  
  println("Before Training");
  float[] myInputDataA1={0,0};
  NN.processInputsToOutputs(myInputDataA1);
  float[] myOutputDataA1={};
  myOutputDataA1=NN.getOutputs();
  println("Feed Forward:  INPUT = 0,0; OUTPUT=" + myOutputDataA1[0]);
   
  float[] myInputDataB1={0,1};
  NN.processInputsToOutputs(myInputDataB1);
  float[] myOutputDataB1={};
  myOutputDataB1=NN.getOutputs();
  println("Feed Forward:  INPUT = 0,1; OUTPUT=" + myOutputDataB1[0]);
   
  float[] myInputDataC1={1,0};
  NN.processInputsToOutputs(myInputDataC1);
  float[] myOutputDataC1={};
  myOutputDataC1=NN.getOutputs();
  println("Feed Forward:  INPUT = 1,0; OUTPUT=" + myOutputDataC1[0]);
   
  float[] myInputDataD1={1,1};
  NN.processInputsToOutputs(myInputDataD1);
  float[] myOutputDataD1={};
  myOutputDataD1=NN.getOutputs();
  println("Feed Forward:  INPUT = 1,1; OUTPUT=" + myOutputDataD1[0]);
 
  println("");
  println("--------------------------------------------");
   
  println("Begin Training");
  NN.autoTrainNetwork(myTrainingInputs,myTrainingOutputs,0.0001,500000);
  println("");
  println("End Training");
  println("");
  println("--------------------------------------------");
  println("Test the neural network");
  float[] myInputDataA2={0,0};
  NN.processInputsToOutputs(myInputDataA2);
  float[] myOutputDataA2={};
  myOutputDataA2=NN.getOutputs();
  println("Feed Forward:  INPUT = 0,0; OUTPUT=" + myOutputDataA2[0]);
   
  float[] myInputDataB2={0,1};
  NN.processInputsToOutputs(myInputDataB2);
  float[] myOutputDataB2={};
  myOutputDataB2=NN.getOutputs();
  println("Feed Forward:  INPUT = 0,1; OUTPUT=" + myOutputDataB2[0]);
   
  float[] myInputDataC2={1,0};
  NN.processInputsToOutputs(myInputDataC2);
  float[] myOutputDataC2={};
  myOutputDataC2=NN.getOutputs();
  println("Feed Forward:  INPUT = 1,0; OUTPUT=" + myOutputDataC2[0]);
   
  float[] myInputDataD2={1,1};
  NN.processInputsToOutputs(myInputDataD2);
  float[] myOutputDataD2={};
  myOutputDataD2=NN.getOutputs();
  println("Feed Forward:  INPUT = 1,1; OUTPUT=" + myOutputDataD2[0]);
  
   
}
 
 
/* ---------------------------------------------------------------------
A connection determines how much of a signal is passed through to the neuron.
--------------------------------------------------------------------  */
 
class Connection{
  float connEntry;
  float weight;
  float connExit;
   
  //This is the default constructor for an Connection
  Connection(){
    randomiseWeight();
  }
   
  //A custom weight for this Connection constructor
  Connection(float tempWeight){
    setWeight(tempWeight);
  }
   
  //Function to set the weight of this connection
  void setWeight(float tempWeight){
    weight=tempWeight;
  }
   
  //Function to randomise the weight of this connection
  void randomiseWeight(){
    setWeight(random(2)-1);
  }
   
  //Function to calculate and store the output of this Connection
  float calcConnExit(float tempInput){
    connEntry = tempInput;
    connExit = connEntry * weight;
    return connExit;
  }
}
 
 
/* -----------------------------------------------------------------
   A neuron does all the processing and calculation to convert an input into an output
--------------------------------------------------------------------- */
 
class Neuron{
  Connection[] connections={};
  float bias;
  float neuronInputValue;
  float neuronOutputValue;
  float deltaError;
   
  //The default constructor for a Neuron
  Neuron(){
  }
   
  /*The typical constructor of a Neuron - with random Bias and Connection weights */
  Neuron(int numOfConnections){
    randomiseBias();
    for(int i=0; i<numOfConnections; i++){
      Connection conn = new Connection();
      addConnection(conn);
    }
  }
   
  //Function to add a Connection to this neuron
  void addConnection(Connection conn){
      connections = (Connection[]) append(connections, conn);
  }
   
  /* Function to return the number of connections associated with this neuron.*/
  int getConnectionCount(){
      return connections.length;
  }
   
  //Function to set the bias of this Neron
  void setBias(float tempBias){
    bias = tempBias;
  }
   
  //Function to randomise the bias of this Neuron
  void randomiseBias(){
    setBias(random(1));
  }
   
  /*Function to convert the inputValue to an outputValue
  Make sure that the number of connEntryValues matches the number of connections */
   
  float getNeuronOutput(float[] connEntryValues){
    if(connEntryValues.length!=getConnectionCount()){
      println("Neuron Error: getNeuronOutput() : Wrong number of connEntryValues");
      exit();
    }
     
    neuronInputValue=0;
     
    /* First SUM all of the weighted connection values (connExit) attached to this neuron. This becomes the neuronInputValue. */
    for(int i=0; i<getConnectionCount(); i++){
      neuronInputValue+=connections[i].calcConnExit(connEntryValues[i]);
    }
     
    //Add the bias to the Neuron's inputValue
    neuronInputValue+=bias;
     
    /* Send the inputValue through the activation function to produce the Neuron's outputValue */
    neuronOutputValue=Activation(neuronInputValue);
     
    //Return the outputValue
    return neuronOutputValue;
  }
   
  //Activation function
  float Activation(float x){
    float activatedValue = 1 / (1 + exp(-1 * x));
    return activatedValue;
  }
   
}
 
class Layer{
  Neuron[] neurons = {};
  float[] layerINPUTs={};
  float[] actualOUTPUTs={};
  float[] expectedOUTPUTs={};
  float layerError;
  float learningRate;
   
   
  /* This is the default constructor for the Layer */
  Layer(int numberConnections, int numberNeurons){
    /* Add all the neurons and actualOUTPUTs to the layer */
    for(int i=0; i<numberNeurons; i++){
      Neuron tempNeuron = new Neuron(numberConnections);
      addNeuron(tempNeuron);
      addActualOUTPUT();
    }
  }
     
   
  /* Function to add an input or output Neuron to this Layer */
  void addNeuron(Neuron xNeuron){
        neurons = (Neuron[]) append(neurons, xNeuron);
  }
   
   
  /* Function to get the number of neurons in this layer */
  int getNeuronCount(){
    return neurons.length;
  }
   
   
  /* Function to increment the size of the actualOUTPUTs array by one. */
  void addActualOUTPUT(){
      actualOUTPUTs = (float[]) expand(actualOUTPUTs,(actualOUTPUTs.length+1));
  }
   
   
  /* Function to set the ENTIRE expectedOUTPUTs array in one go. */
  void setExpectedOUTPUTs(float[] tempExpectedOUTPUTs){
    expectedOUTPUTs=tempExpectedOUTPUTs;
  }
   
   
  /* Function to clear ALL values from the expectedOUTPUTs array */
  void clearExpectedOUTPUT(){
       expectedOUTPUTs = (float[]) expand(expectedOUTPUTs, 0);
  }
   
   
  /* Function to set the learning rate of the layer */
  void setLearningRate(float tempLearningRate){
    learningRate=tempLearningRate;
  }
   
   
  /* Function to set the inputs of this layer */
  void setInputs(float[] tempInputs){
    layerINPUTs=tempInputs;
  }
   
   
   
  /* Function to convert ALL the Neuron input values into Neuron output values in this layer, through a special activation function. */
  void processInputsToOutputs(){
     
    /* neuronCount is used a couple of times in this function. */
    int neuronCount = getNeuronCount();
     
    /* Check to make sure that there are neurons in this layer to process the inputs */
    if(neuronCount>0) {
      /* Check to make sure that the number of inputs matches the number of Neuron Connections. */
      if(layerINPUTs.length!=neurons[0].getConnectionCount()){
        println("Error in Layer: processInputsToOutputs: The number of inputs do NOT match the number of Neuron connections in this layer");
        exit();
      } else {
        /* The number of inputs are fine : continue
           Calculate the actualOUTPUT of each neuron in this layer,
           based on their layerINPUTs (which were previously calculated).
           Add the value to the layer's actualOUTPUTs array. */
        for(int i=0; i<neuronCount;i++){
          actualOUTPUTs[i]=neurons[i].getNeuronOutput(layerINPUTs);
        }
      }
    }else{
      println("Error in Layer: processInputsToOutputs: There are no Neurons in this layer");
      exit();
    }
  }
   
   
  /* Function to get the error of this layer */
  float getLayerError(){
    return layerError;
  }
   
   
  /* Function to set the error of this layer */
  void setLayerError(float tempLayerError){
    layerError=tempLayerError;
  }
   
   
  /* Function to increase the layerError by a certain amount */
  void increaseLayerErrorBy(float tempLayerError){
    layerError+=tempLayerError;
  }
   
   
  /* Function to calculate and set the deltaError of each neuron in the layer */
  void setDeltaError(float[] expectedOutputData){
    setExpectedOUTPUTs(expectedOutputData);
    int neuronCount = getNeuronCount();
    /* Reset the layer error to 0 before cycling through each neuron */
    setLayerError(0);
     for(int i=0; i<neuronCount;i++){
       neurons[i].deltaError = actualOUTPUTs[i]*(1-actualOUTPUTs[i])*(expectedOUTPUTs[i]-actualOUTPUTs[i]);
        
       /* Increase the layer Error by the absolute difference between the calculated value (actualOUTPUT) and the expected value (expectedOUTPUT). */
       increaseLayerErrorBy(abs(expectedOUTPUTs[i]-actualOUTPUTs[i]));
     }
  }
   
   
  /* Function to train the layer : which uses a training set to adjust the connection weights and biases of the neurons in this layer */
  void trainLayer(float tempLearningRate){
    setLearningRate(tempLearningRate);
     
    int neuronCount = getNeuronCount();
     
    for(int i=0; i<neuronCount;i++){
      /* update the bias for neuron[i] */
      neurons[i].bias += (learningRate * 1 * neurons[i].deltaError);
       
      /* update the weight of each connection for this neuron[i] */
      for(int j=0; j<neurons[i].getConnectionCount(); j++){
          neurons[i].connections[j].weight += (learningRate * neurons[i].connections[j].connEntry * neurons[i].deltaError);
      }  
    }
  }
}
 
/* -------------------------------------------------------------
   The Neural Network class is a container to hold and manage all the layers
   ---------------------------------------------------------------- */
 
class NeuralNetwork{
  Layer[] layers = {};
  float[] arrayOfInputs={};
  float[] arrayOfOutputs={};
  float learningRate;
  float networkError;
  float trainingError;
  int retrainChances=0;
   
  NeuralNetwork(){
    /* the default learning rate of a neural network is set to 0.1, which can changed by the setLearningRate(lR) function. */
    learningRate=0.1;
  }
   
   
   
  /* Function to add a Layer to the Neural Network */
  void addLayer(int numConnections, int numNeurons){
    layers = (Layer[]) append(layers, new Layer(numConnections,numNeurons));
  }
 
 
 
  /* Function to return the number of layers in the neural network */
  int getLayerCount(){
      return layers.length;
  }
   
   
   
  /* Function to set the learningRate of the Neural Network */
  void setLearningRate(float tempLearningRate){
    learningRate=tempLearningRate;
  }
   
   
   
  /* Function to set the inputs of the neural network */
  void setInputs(float[] tempInputs){
    arrayOfInputs=tempInputs;
  }
   
   
   
  /* Function to set the inputs of a specified layer */
  void setLayerInputs(float[] tempInputs, int layerIndex){
    if(layerIndex>getLayerCount()-1){
      println("NN Error: setLayerInputs: layerIndex=" + layerIndex + " exceeded limits= " + (getLayerCount()-1));
    } else {
      layers[layerIndex].setInputs(tempInputs);
    }
  }
   
   
   
  /* Function to set the outputs of the neural network */
  void setOutputs(float[] tempOutputs){
    arrayOfOutputs=tempOutputs;
  }
   
   
   
  /* Function to return the outputs of the Neural Network */
  float[] getOutputs(){
    return arrayOfOutputs;
  }
   
   
   
  /* Function to process the Neural Network's input values and convert them to an output pattern using ALL layers in the network */
  void processInputsToOutputs(float[] tempInputs){
    setInputs(tempInputs);
     
    /* Check to make sure that the number of NeuralNetwork inputs matches the Neuron Connection Count in the first layer. */
    if(getLayerCount()>0){
      if(arrayOfInputs.length!=layers[0].neurons[0].getConnectionCount()){
        println("NN Error: processInputsToOutputs: The number of inputs do NOT match the NN");
        exit();
      } else {
        /* The number of inputs are fine : continue */
        for(int i=0; i<getLayerCount(); i++){
           
          /*Set the INPUTs for each layer: The first layer gets it's input data from the NN, whereas the 2nd and subsequent layers get their input data from the previous layer's actual output. */
          if(i==0){
            setLayerInputs(arrayOfInputs,i);
          } else {
            setLayerInputs(layers[i-1].actualOUTPUTs, i);
          }
           
          /* Now that the layer has had it's input values set, it can now process this data, and convert them into an output using the layer's neurons. The outputs will be used as inputs in the next layer (if available). */
          layers[i].processInputsToOutputs();
        }
        /* Once all the data has filtered through to the end of network, we can grab the actualOUTPUTs of the LAST layer
           These values become or will be set to the NN output values (arrayOfOutputs), through the setOutputs function call. */
        setOutputs(layers[getLayerCount()-1].actualOUTPUTs);
      }
    }else{
      println("Error: There are no layers in this Neural Network");
      exit();
    }
  }
   
   
   
   
  /* Function to train the entire network using an array. */
  void trainNetwork(float[] inputData, float[] expectedOutputData){
    /* Populate the ENTIRE network by processing the inputData. */
    processInputsToOutputs(inputData);
     
    /* train each layer - from back to front (back propagation) */
    for(int i=getLayerCount()-1; i>-1; i--){
      if(i==getLayerCount()-1){
        layers[i].setDeltaError(expectedOutputData);
        layers[i].trainLayer(learningRate);
        networkError=layers[i].getLayerError();
      } else {
        /* Calculate the expected value for each neuron in this layer (eg. HIDDEN LAYER) */
        for(int j=0; j<layers[i].getNeuronCount(); j++){
          /* Reset the delta error of this neuron to zero. */
          layers[i].neurons[j].deltaError=0;
          /* The delta error of a hidden layer neuron is equal to the SUM of [the PRODUCT of the connection.weight and error of the neurons in the next layer(eg OUTPUT Layer)]. */
          /* Connection#1 of each neuron in the output layer connect with Neuron#1 in the hidden layer */
          for(int k=0; k<layers[i+1].getNeuronCount(); k++){
            layers[i].neurons[j].deltaError += (layers[i+1].neurons[k].connections[j].weight * layers[i+1].neurons[k].deltaError);
          }
          /* Now that we have the sum of Errors x weights attached to this neuron. We must multiply it by the derivative of the activation function. */
          layers[i].neurons[j].deltaError *= (layers[i].neurons[j].neuronOutputValue * (1-layers[i].neurons[j].neuronOutputValue));
        }
        /* Now that you have all the necessary fields populated, you can now Train this hidden layer and then clear the Expected outputs, ready for the next round. */
        layers[i].trainLayer(learningRate);
        layers[i].clearExpectedOUTPUT();
      }
    }
  }
   
   
   
   
   
  /* Function to train the entire network, using an array of input and expected data within an ArrayList */
  void trainingCycle(ArrayList trainingInputData, ArrayList trainingExpectedData, Boolean trainRandomly){
      int dataIndex;
       
      /* re-initialise the training Error with every cycle */
      trainingError=0;
       
      /* Cycle through the training data either randomly or sequentially */
      for(int i=0; i<trainingInputData.size(); i++){
        if(trainRandomly){
          dataIndex=(int) (random(trainingInputData.size()));
        } else {
          dataIndex=i;
        }
  
        trainNetwork((float[]) trainingInputData.get(dataIndex),(float[]) trainingExpectedData.get(dataIndex));
         
        /* Use the networkError variable which is calculated at the end of each individual training session to calculate the entire trainingError. */
        trainingError+=abs(networkError);
      }
  }
   
   
   
   
   
  /* Function to train the network until the Error is below a specific threshold */
  void autoTrainNetwork(ArrayList trainingInputData, ArrayList trainingExpectedData, float trainingErrorTarget, int cycleLimit){
    trainingError=9999;
    int trainingCounter=0;
     
     
    /* cycle through the training data until the trainingError gets below trainingErrorTarget (eg. 0.0005) or the training cycles have exceeded the cycleLimit
 
variable (eg. 10000). */
    while(trainingError>trainingErrorTarget && trainingCounter<cycleLimit){
       
      /* re-initialise the training Error with every cycle */
      trainingError=0;
       
      /* Cycle through the training data randomly */
      trainingCycle(trainingInputData, trainingExpectedData, true);
       
      /* increment the training counter to prevent endless loop */
      trainingCounter++;
    }
     
    /* Due to the random nature in which this neural network is trained. There may be occasions when the training error may drop below the threshold
       To check if this is the case, we will go through one more cycle (but sequentially this time), and check the trainingError for that cycle
       If the training error is still below the trainingErrorTarget, then we will end the training session.
       If the training error is above the trainingErrorTarget, we will continue to train. It will do this check a  Maximum of 9 times. */
    if(trainingCounter<cycleLimit){
       trainingCycle(trainingInputData, trainingExpectedData, false);
       trainingCounter++;
       
       if(trainingError>trainingErrorTarget){
         if (retrainChances<10){
           retrainChances++;
           autoTrainNetwork(trainingInputData, trainingExpectedData,trainingErrorTarget, cycleLimit);
         }
       }
        
    } else {
      println("CycleLimit has been reached. Has been retrained " + retrainChances + " times.  Error is = " + trainingError);
    }  
  }
}

The above code was formatted using hilite.me

ScottC 15 Aug 14:06

arduinobasics back propagation best arduino blog code example neural network processing processing.org project tutorial

Neural Network (Part 6) : Back Propagation, a worked example

A worked example of a Back-propagation training cycle.

In this example we will create a 2 layer network (as seen above), to accept 2 readings, and produce 2 outputs. The readings are (0,1) and the expectedOutputs in this example are (1,0).

Step 1: Create the network

NeuralNetwork NN = new NeuralNetwork();

NN.addLayer(2,2);

float[] readings = {0,1};

float[] expectedOutputs = {1,0};

NN.trainNetwork(readings,expectedOutputs);

This neural network will have randomised weights and biases when created.

Let us assume that the network generates the following random variables:

LAYER1.Neuron1

Layer1.Neuron1.Connection1.weight = cW111 = 0.3

Layer1.Neuron1.Connection2.weight = cW112 = 0.8

Layer1.Neuron1.Bias = bW11 = 0.5

LAYER1.Neuron2

Layer1.Neuron2.Connection1.weight = cW121 = 0.1

Layer1.Neuron2.Connection2.weight = cW122 = 0.1

Layer1.Neuron2.Bias = bW12 = 0.2

LAYER2.Neuron1

Layer2.Neuron1.Connection1.weight = cW211 = 0.6

Layer2.Neuron1.Connection2.weight = cW212 = 0.4

Layer2.Neuron1.Bias = bW21 = 0.4

LAYER2.Neuron2

Layer2.Neuron2.Connection1.weight = cW221 = 0.9

Layer2.Neuron2.Connection2.weight = cW222 = 0.9

Layer2.Neuron2.Bias = bW22 = 0.5

Step 2: Process the Readings through the Neural Network

a) Provide the Readings to the first layer, and calculate the neuron outputs

The readings provided to the neural network is (0,1), which go straight through to the first layer (layer1).

Starting with Layer 1:

Layer1.INPUT1 = 0

Layer1.INPUT2 =1

Calculate Layer1.Neuron1.NeuronOutput

ConnExit (cEx111) = ConnEntry (cEn111) x Weight (cW111) = 0 x 0.3 = 0;

ConnExit (cEx112) = ConnEntry (cEn112) x Weight (cW112) = 1 x 0.8 = 0.8;

Bias (bEx11) = ConnEntry (1) x Weight (bW11) = 1 x 0.4 = 0.4

NeuronInputValue11 = 0 + 0.8 + 0.4 = 1.2

NeuronOutputValue11 = 1/(1+EXP(-1 x 1.2)) = 0.768525

Calculate Layer1.Neuron2.NeuronOutput

ConnExit (cEx121) = ConnEntry (cEn121) x Weight (cW121) = 0 x 0.1 = 0;

ConnExit (cEx122) = ConnEntry (cEn122) x Weight (cW122) = 1 x 0.1 = 0.1;

Bias (bEx12) = ConnEntry (1) x Weight (bW12) = 1 x 0.2 = 0.2

NeuronInputValue12 = 0 + 0.1 + 0.2 = 0.3

NeuronOutputValue12 = 1/(1+EXP(-1 x 0.3)) = 0.574443

b) Provide LAYER2 with Layer 1 Outputs.

Now lets move to Layer 2:

Layer2.INPUT1 = NeuronOutputValue11 = 0.768525

Layer2.INPUT2 = NeuronOutputValue12 = 0.574443

Calculate Layer2.Neuron1.NeuronOutput

ConnExit (cEx211) = (cEn211) x Weight (cW211) = 0.768525 x 0.6 = 0.461115;

ConnExit (cEx212) = (cEn212) x Weight (cW212) = 0.574443 x 0.4 = 0.229777;

Bias (bEx21) = ConnEntry (1) x Weight (bW21) = 1 x 0.4 = 0.4

NeuronInputValue21 = 0.461115 + 0.229777 + 0.4 = 1.090892

NeuronOutputValue21 = 1/(1+EXP(-1 x 1.090892)) = 0.74855

Calculate Layer2.Neuron2.NeuronOutput

ConnExit (cEx221) = (cEn221) x Weight (cW221) = 0.768525 x 0.1 = 0.076853;

ConnExit (cEx222) = (cEn222) x Weight (cW222) = 0.574443 x 0.1 = 0.057444;

Bias(bEx22) = ConnEntry (1) x Weight (bW22) = 1 x 0.5 = 0.5

NeuronInputValue22 = 0.076853 + 0.057444 + 0.5 = 0.634297

NeuronOutputValue22 = 1/(1+EXP(-1 x 0.634297)) = 0.653463

Step 3) Calculate the delta error for neurons in layer 2

-Because layer 2 is the last layer in this neural network -

we will use the expected output data (1,0) to calculate the delta error.

LAYER2.Neuron1:

Let Layer2.ExpectedOutput1 = eO21 = 1

Layer2.ActualOutput1= aO21 = NeuronOutputValue21= 0.74855

Layer2.Neuron1.deltaError1 = dE21

dE21 = aO21 x (1 - aO21) x (eO21 - aO21)

= (0.74855) x (1 - 0.74855) x (1 - 0.74855)

= (0.74855) x (0.25145) x (0.25145)

= 0.047329

LAYER2.Neuron2:

Let Layer2.ExpectedOutput2 = eO22 = 0

Layer2.ActualOutput2 = aO22 = NeuronOutputValue22 = 0.653463

Layer2.Neuron2.deltaError = dE22

dE22 = aO22 x (1 - aO22) x (eO22 - aO22)

= (0.653463) x (1 - 0.653463) x (0 - 0.653463)

= (0.653463) x (0.346537) x (-0.653463)

= -0.14797

Step 4) Calculate the delta error for neurons in layer 1

LAYER1.Neuron1 delta Error calculation

Let Layer1.Neuron1.deltaError = dE11

Layer1.actualOutput1 = aO11 = NeuronOutputValue11 = 0.768525

Layer2.Neuron1.Connection1.weight = cW211 = 0.6

Layer2.Neuron1.deltaError = dE21 = 0.047329

Layer2.Neuron2.Connection1.weight = cW221 = 0.9

Layer2.Neuron2.deltaError = dE22 = -0.14797

dE11 = (aO11) x (1 - aO11) x ( [cW211 x dE21] + [cW221 x dE22] )

= (0.768525) x (1 - 0.768525) x ([0.6 x 0.047329] + [ 0.9 x -0.14797] )

= -0.01864

LAYER1.Neuron2 delta Error calculation

Let Layer1.Neuron2.deltaError = dE12

Layer1.actualOutput2 = aO12 = NeuronOutputValue12 = 0.574443

Layer2.Neuron1.Connection2.weight = cW212 = 0.4

Layer2.Neuron1.deltaError = dE21 = 0.047329

Layer2.Neuron2.Connection2.weight = cW222 = 0.9

Layer2.Neuron2.deltaError = dE22 = -0.14797

dE12 = (aO12) x (1 - aO12) x ( [cW212 x dE21] + [cW222 x dE22] )

= (0.574443) x (1 - 0.574443) x ([0.4 x 0.047329] + [ 0.9 x -0.14797] )

= -0.02793

Step 5) Update Layer_2 neuron connection weights and bias (with a learning rate (LR) = 0.1)

Layer 2, Neuron 1 calculations:

Let

Layer2.Neuron1.Connection1.New_weight = New_cW211

Layer2.Neuron1.Connection1.Old_weight = Old_cW211 = 0.6

Layer2.Neuron1.Connection1.connEntry = cEn211 = 0.768525

Layer2.Neuron1.deltaError = dE21 = 0.047329

New_cW211 = Old_cW211 + (LR x cEn211 x dE21)

= 0.6 + (0.1 x 0.768525 x 0.047329)

= 0.6 + ( 0.003627)

= 0.603627

Layer2.Neuron1.Connection2.New_weight = New_cW212

Layer2.Neuron1.Connection2.Old_weight = Old_cW212 = 0.4

Layer2.Neuron1.Connection2.connEntry = cEn212 = 0.574443

Layer2.Neuron1.deltaError = dE21 = 0.047329

New_cW212 = Old_cW212 + (LR x cEn212 x dE21)

= 0.4 + (0.1 x 0.574443 x 0.047329)

= 0.4 + (0.002719)

= 0.402719

Layer2.Neuron1.New_Bias = New_Bias21

Layer2.Neuron1.Old_Bias = Old_Bias21 = 0.4

Layer2.Neuron1.deltaError = dE21 = 0.047329

New_Bias21 = Old_Bias21 + (LR x 1 x de21)

= 0.4 + (0.1 x 1 x 0.047329)

= 0.4 + (0.0047329)

= 0.4047329

--------------------------------------------------------------------

Layer 2, Neuron 2 calculations:

Layer2.Neuron2.Connection1.New_weight = New_cW221

Layer2.Neuron2.Connection1.Old_weight = Old_cW221 = 0.9

Layer2.Neuron2.Connection1.connEntry = cEn221 = 0.768525

Layer2.Neuron2.deltaError = dE22 = -0.14797

New_cW221 = Old_cW221 + (LR x cEn221 x dE22)

= 0.9 + (0.1 x 0.768525 x -0.14797)

= 0.9 + ( -0.01137)

= 0.88863

Layer2.Neuron2.Connection2.New_weight = New_cW222

Layer2.Neuron2.Connection2.Old_weight = Old_cW222 = 0.9

Layer2.Neuron2.Connection2.connEntry = cEn222 = 0.574443

Layer2.Neuron2.deltaError = dE22 = -0.14797

New_cW222 = Old_cW222 + (LR x cEn222 x dE22)

= 0.9 + (0.1 x 0.574443 x -0.14797)

= 0.9 + (-0.0085)

= 0.8915

Layer2.Neuron2.New_Bias = New_Bias22

Layer2.Neuron2.Old_Bias = Old_Bias22 = 0.5

Layer2.Neuron2.deltaError = dE22 = -0.14797

New_Bias22 = Old_Bias22 + (LR x 1 x de22)

= 0.5 + (0.1 x 1 x -0.14797)

= 0.5 + (-0.014797)

= 0.485203

--------------------------------------------------------------------------

Step 6) Update Layer_1 neuron connection weights and bias.

Layer 1, Neuron 1 calculations:

Let

Layer1.Neuron1.Connection1.New_weight = New_cW111

Layer1.Neuron1.Connection1.Old_weight = Old_cW111 = 0.3

Layer1.Neuron1.Connection1.connEntry = cEn111 = 0

Layer1.Neuron1.deltaError = dE11 = -0.01864

New_cW111 = Old_cW111 + (LR x cEn111 x dE11)

= 0.3 + (0.1 x 0 x -0.01864)

= 0.3 + ( 0 )

= 0.3

Layer1.Neuron1.Connection2.New_weight = New_cW112

Layer1.Neuron1.Connection2.Old_weight = Old_cW112 = 0.8

Layer1.Neuron1.Connection2.connEntry = cEn112 = 1

Layer1.Neuron1.deltaError = dE11 = -0.01864

New_cW112 = Old_cW112 + (LR x cEn112 x dE11)

= 0.8 + (0.1 x 1 x -0.01864)

= 0.8 + (-0.001864)

= 0.798136

Layer1.Neuron1.New_Bias = New_Bias11

Layer1.Neuron1.Old_Bias = Old_Bias11 = 0.5

Layer1.Neuron1.deltaError = dE11 = -0.01864

New_Bias11 = Old_Bias11 + (LR x 1 x dE11)

= 0.5 + (0.1 x 1 x -0.01864 )

= 0.5 + (-0.001864)

= 0.498136

--------------------------------------------------------------------

Layer 1, Neuron 2 calculations:

Layer1.Neuron2.Connection1.New_weight = New_cW121

Layer1.Neuron2.Connection1.Old_weight = Old_cW121 = 0.1

Layer1.Neuron2.Connection1.connEntry = cEn121 = 0

Layer1.Neuron2.deltaError = dE12 = -0.02793

New_cW121 = Old_cW121 + (LR x cEn121 x dE12)

= 0.1 + (0.1 x 0 x -0.02793 )

= 0.1 + (0)

= 0.1

Layer1.Neuron2.Connection2.New_weight = New_cW122

Layer1.Neuron2.Connection2.Old_weight = Old_cW122 = 0.1

Layer1.Neuron2.Connection2.connEntry = cEn122 = 1

Layer1.Neuron2.deltaError = dE12 = -0.02793

New_cW122 = Old_cW122 + (LR x cEn122 x dE12)

= 0.1 + (0.1 x 1 x -0.02793)

= 0.1 + (-0.002793)

= 0.097207

Layer1.Neuron2.New_Bias = New_Bias12

Layer1.Neuron2.Old_Bias = Old_Bias12 = 0.2

Layer1.Neuron2.deltaError = dE12 = -0.02793

New_Bias12 = Old_Bias12 + (LR x 1 x de12)

= 0.2 + (0.1 x 1 x -0.02793)

= 0.2 + (-0.002793)

= 0.197207

----------------------------------------------------------------------

All done. That was just one training cycle. Thank goodness we have computers !

A computer can process these calculations really quickly, and depending on how complicated your neural network is (ie. number of layers, and number of neurons per layer), you may find that the training procedure may take some time. But believe me, if you have designed it right, it is well worth the wait.

Because once you have the desired weights and bias values set up, you are good to go, and as you receive data, the computer can do a single forward pass in a fraction of a second, and you will get your desired output, hopefully :)

Here is a complete Processing.org script that demonstrates the use of my neural network.

Neural Network (Part 7): Cut and Paste Code (click here).

If you liked my tutorial - please let me know in the comments. It is sometimes hard to know if anyone is actually reading this stuff. If you use my code in your own project, I am also happy for you to leave a link to a YouTube video etc in the comments also.

To go back to the table of contents click here

ScottC 14 Aug 10:11

arduinobasics back propagation best arduino blog feed forward neural network processing.org project training tutorial

Neural Network (Part 5): The Back Propagation process

Back-propagation

Back propagation is the process by which you move backwards through the neural network to adjust the weights and biases so as to reduce the total error of the network. The total error of the network is essentially the difference between the end results (actual Outputs) and the expected results. If you expected to get a result of 1, but instead got a 0: you would go back through the network and tweak each of the weights (and bias) values so that your end result was a little bit closer to 1 than before.

The process of back-propagation is such that larger errors and larger weights and biases that create those errors are penalised more than their smaller counterparts. Bigger weights have a bigger influence on the final outcome than smaller weights, and are therefore penalised more for incorrect answers.

After many training cycles, the neural network reaches a stage of equilibrium (not quite, but close enough), whereby the tweaking is insignificant to the final outcome.

If you under-train, then you will get the wrong result more often than desired.

If you over-train, then the neural network will not be able to "think outside the sqaure", so to speak.

So how do you propagate backwards ??

Step 1: Feed-forward pass through:

Send some data through the network to populate all the variables. This feed-forward pass allows you calculate your actualOUTPUTs, which you will use to compare against your expectedOUTPUTs.

Step 2: Calculate delta-error for the neurons in the last layer (output layer).

The delta-error calculation for the neuron(s) in the last layer of the neural network is a liitle bit different than the other layers. You can work this out once you calculate the actualOUTPUTs from the feedforward pass.

Let Last Layer Neuron1.deltaError = LLN1.dE

Last Layer.actualOutput1 = aO1 <--- This is the same as the Neuron1 Output Value

Last Layer.expectedOutput1 = exO1

LLN1.dE = (aO1) x (1-aO1) x (exO1 - aO1);

Once you have calculated the deltaError for every neuron in the last layer (output layer), you can move onto the next step.

Step 3: Calculate the delta-error for the hidden layer neurons

The hidden layers for this neural network, is any layer in the neural network, that is not the last layer. However, each layer should sit like ducks in a row. And we are now going to calculate the delta error for the second last layer in the neural network. This could in theory be the first layer in the network (if this network only had 2 layers).

HLN = Hidden Layer Neuron,

LLN = Last Layer Neuron,

aO=actualOUTPUT,

dE=deltaError

HLN.dE = (HLN.aO) x (1-HLN.aO) x (Sum of [LLN.dE x LLN to HLN connection weight])

Keep moving back through the network layers until you reach the 1st layer (ie, you run out of layers).

Step 4: Update the weights of the connections and Bias of neuron.

a) Multiply the neuron's deltaError which was calculated in either step 2 or 3, by the learning rate (0.1), and by the connection's connEntry value.

b) Then add this calculated value (in Step (4a)) to the current weight of the connection.

neuron.connections[i].weight += (learningRate * neuron.connections[i].connEntry * neuron.deltaError);

The bias is like a connection with a constant connEntry of 1, therefore the calculation is

neuron.bias += (learningRate * 1 * neuron.deltaError);

Up Next: Neural Network (Part 6):

Back Propagation - a fully worked example.

To go back to the table of contents click here

ScottC 12 Aug 16:27

arduinobasics back propagation best arduino blog learning neural network neuron processing.org programming project tutorial

Neural Network (Part 4): The Neural Network class

The Neural Network

Finally, we made it to the Neural Network class. This is the top level class that manages the communication between the layers. This class provides the necessary glue to hold all the layers together. It also controls the flow of information forwards and backwards from layer to layer. Lets have a look at a simple 2 layer neural network.

The above neural network starts with 2 inputs in Layer1 and finishes with 2 outputs in Layer 2.

This Neural Network structure is very modular in design. Layers can be added quite easily without affecting the functionality of the neural network code. The only layer that is treated a little bit differently from other layers in the neural network, is the last layer. However, any/all preceding layers are treated exactly the same. And the differences in the last layer, only really come into effect in Neural Network training.

When building my network, I just need to make sure that the number of outputs (or neurons) in the current layer match the number of connections in the next. If I wanted to create a neural network, that accepted 3 input signals from the outside world, to process them with 10 neurons, but only wanted to output one result... I could build the neural network in the following way.

addLayer(3,10) : This first layer would have 3 layerINPUTs and 10 neurons

addLayer(10,1) : This second (and last) layer would have 10 layerINPUTs and 1 neuron

The neural network class would manage these two layers, to ensure that information was passed from one to the other seemlessly. Here is the code for the Neural Network class that would make it possible:

/* -------------------------------------------------------------------------------------

   The Neural Network class is a container to hold and manage all the layers 

   ------------------------------------------------------------------------------------- */



class NeuralNetwork{

  Layer[] layers = {};

  float[] arrayOfInputs={};

  float[] arrayOfOutputs={};

  float learningRate;

  float networkError;

  float trainingError;

  int retrainChances=0;

  

  NeuralNetwork(){

    /* the default learning rate of a neural network is set to 0.1, which can changed by the setLearningRate(lR) function. */

    learningRate=0.1;

  }

  

  

  

  /* Function to add a Layer to the Neural Network */

  void addLayer(int numConnections, int numNeurons){

    layers = (Layer[]) append(layers, new Layer(numConnections,numNeurons));

  }







  /* Function to return the number of layers in the neural network */

  int getLayerCount(){

      return layers.length;

  }

  

  

  

  /* Function to set the learningRate of the Neural Network */

  void setLearningRate(float tempLearningRate){

    learningRate=tempLearningRate;

  }

  

  

  

  /* Function to set the inputs of the neural network */

  void setInputs(float[] tempInputs){

    arrayOfInputs=tempInputs;

  }

  

  

  

  /* Function to set the inputs of a specified layer */

  void setLayerInputs(float[] tempInputs, int layerIndex){

    if(layerIndex>getLayerCount()-1){

      println("NN Error: setLayerInputs: layerIndex=" + layerIndex + " exceeded limits= " + (getLayerCount()-1));

    } else {

      layers[layerIndex].setInputs(tempInputs);

    }

  }

  

  

  

  /* Function to set the outputs of the neural network */

  void setOutputs(float[] tempOutputs){

    arrayOfOutputs=tempOutputs;

  }

  

  

  

  /* Function to return the outputs of the Neural Network */

  float[] getOutputs(){

    return arrayOfOutputs;

  }

  

  

  

  /* Function to process the Neural Network's input values and convert them to an output pattern using ALL layers in the network */

  void processInputsToOutputs(float[] tempInputs){

    setInputs(tempInputs);

    

    /* Check to make sure that the number of NeuralNetwork inputs matches the Neuron Connection Count in the first layer. */

    if(getLayerCount()>0){

      if(arrayOfInputs.length!=layers[0].neurons[0].getConnectionCount()){

        println("NN Error: processInputsToOutputs: The number of inputs do NOT match the NN");

        exit();

      } else {

        /* The number of inputs are fine : continue */

        for(int i=0; i<getLayerCount(); i++){

          

          /*Set the INPUTs for each layer: The first layer gets it's input data from the NN whereas the 2nd and subsequent layers get their input data from the previous layer's actual output. */

          if(i==0){

            setLayerInputs(arrayOfInputs,i);

          } else {

            setLayerInputs(layers[i-1].actualOUTPUTs, i);

          }

          

          /* Now that the layer has had it's input values set, it can now process this data, and convert them into an output using the layer's neurons. The outputs will be used as inputs in the next layer (if available). */

          layers[i].processInputsToOutputs();

        }

        /* Once all the data has filtered through to the end of network, we can grab the actualOUTPUTs of the LAST layer

           These values become or will be set to the NN output values (arrayOfOutputs), through the setOutputs function call. */

        setOutputs(layers[getLayerCount()-1].actualOUTPUTs);

      }

    }else{

      println("Error: There are no layers in this Neural Network");

      exit();

    }

  }

  

  

  

  

  /* Function to train the entire network using an array. */

  void trainNetwork(float[] inputData, float[] expectedOutputData){

    /* Populate the ENTIRE network by processing the inputData. */

    processInputsToOutputs(inputData);

    

    /* train each layer - from back to front (back propagation) */

    for(int i=getLayerCount()-1; i>-1; i--){

      if(i==getLayerCount()-1){

        layers[i].setDeltaError(expectedOutputData);

        layers[i].trainLayer(learningRate);

        networkError=layers[i].getLayerError();

      } else {

    /* Calculate the expected value for each neuron in this layer (eg. HIDDEN LAYER) */

        for(int j=0; j<layers[i].getNeuronCount(); j++){

          /* Reset the delta error of this neuron to zero. */

          layers[i].neurons[j].deltaError=0;

   /* The delta error of a hidden layer neuron is equal to the SUM of [the PRODUCT of the connection.weight and error of the neurons in the next layer(eg OUTPUT Layer)].      Connection#1 of each neuron in the output layer connect with Neuron#1 in the hidden layer */

          for(int k=0; k<layers[i+1].getNeuronCount(); k++){

            layers[i].neurons[j].deltaError += (layers[i+1].neurons[k].connections[j].weight * layers[i+1].neurons[k].deltaError);

          }

          /* Now that we have the sum of Errors x weights attached to this neuron. 

             We must multiply it by the derivative of the activation function. */

          layers[i].neurons[j].deltaError *= (layers[i].neurons[j].neuronOutputValue * (1-layers[i].neurons[j].neuronOutputValue));

        }

        /* Now that you have all the necessary fields populated, you can now

           Train this hidden layer and then clear the Expected outputs, ready for the next round */

        layers[i].trainLayer(learningRate);

        layers[i].clearExpectedOUTPUT();

      }

    } 

  }

  

  

  

  

  

  /* Function to train the entire network, using an array of input and expected data within an ArrayList */

  void trainingCycle(ArrayList trainingInputData, ArrayList trainingExpectedData, Boolean trainRandomly){

      int dataIndex;

      

      /* re-initialise the training Error with every cycle */

      trainingError=0;

      

      /* Cycle through the training data either randomly or sequentially */

      for(int i=0; i<trainingInputData.size(); i++){

        if(trainRandomly){

          dataIndex=(int) (random(trainingInputData.size()));

        } else {

          dataIndex=i;

        }

 

        trainNetwork((float[]) trainingInputData.get(dataIndex),(float[]) trainingExpectedData.get(dataIndex));

        

        /* Use the networkError variable which is calculated at the end of each individual training session to calculate the entire trainingError. */

        trainingError+=abs(networkError);

      }

  }

  

  

  

  

  

  /* Function to train the network until the Error is below a specific threshold */

  void autoTrainNetwork(ArrayList trainingInputData, ArrayList trainingExpectedData, float trainingErrorTarget, int cycleLimit){

    trainingError=9999;

    int trainingCounter=0;

    

    

    /* cycle through the training data until the trainingError gets below trainingErrorTarget (eg. 0.0005) or the training cycles have exceeded the cycleLimit variable (eg. 10000). */

    while(trainingError>trainingErrorTarget && trainingCounter<cycleLimit){

      

      /* re-initialise the training Error with every cycle */

      trainingError=0;

      

      /* Cycle through the training data randomly */

      trainingCycle(trainingInputData, trainingExpectedData, true);

      

      /* increment the training counter to prevent endless loop */

      trainingCounter++;

    }

    

    /* Due to the random nature in which this neural network is trained. There may be occasions when the training error may drop below the threshold. To check if this is the case, we will go through one more cycle (but sequentially this time), and check the trainingError for that cycle. If the training error is still below the trainingErrorTarget, then we will end the training session. If the training error is above the trainingErrorTarget, we will continue to train. It will do this check a  Maximum of 9 times. */

    if(trainingCounter<cycleLimit){

       trainingCycle(trainingInputData, trainingExpectedData, false);

       trainingCounter++;

      

       if(trainingError>trainingErrorTarget){

         if (retrainChances<10){

           retrainChances++;

           autoTrainNetwork(trainingInputData, trainingExpectedData,trainingErrorTarget, cycleLimit);

         }

       }

       

    } else {

      println("CycleLimit has been reached. Has been retrained " + retrainChances + " times.  Error is = " + trainingError);

    }   

  } 

}

code formatter

The neural network constructor: NeuralNetwork() - automatically sets the learning rate to 0.1. Other than that, the Neural Network object is an empty shell waiting to be filled. The main setup function of the Neural Network class is the addLayer() function, which adds a layer with a specified number of connections and neurons.

Here are the functions of the Neural Network (NN) class:

addLayer() : adds a layer to the NN (from left to right)
getLayerCount() : returns the number of layers in the NN
setLearningRate(): sets the learning Rate to a specified value.
setInputs(): sets the inputs of the NN, and become the layerINPUTs of the 1st layer
setLayerInputs(): set the inputs of a specified layer
setOutputs(): set the outputs of the NN= same as the actualOUTPUTs of the last layer.
getOutputs(): returns the outputs of the NN
processInputsToOutputs(): Converts the NN inputs into outputs by feeding through layers.
trainNetwork(): uses a training set to train the neural network (using an Array).
trainingCycle(): uses a training set to train the neural network (using an ArrayList).
autoTrainNetwork(): cycles through the training data until a specific condition is met

Ok - so we now have all of the structural components required to build a feed forward neural network. And here is how you would create it. Let us build a neural network that accepts data from 4 sensors and has 3 layers . The layers will have 6, 8 and 2 neurons respectively...

NeuralNetwork NN = new NeuralNetwork();
NN.addLayer(4,6);
NN.addLayer(6,8);
NN.addLayer(8,2);

Perfect, we have just created an entire neural network, with randomised weights and biases etc etc.

Unfortunately, the neural network is not that useful at the moment. Before we can even start to use it, we need to put it through school. We need to teach it.

Try to imagine a colour that you have never seen before. Hard isn't it ? That is how the Neural Network feels. So before you can get it to make any sort of classifications, you have to show it some examples of what you are looking for. Once the neural network can make sense of your examples, you use a "validation set" to put it through it's paces. If it performs well, then you are good to go, otherwise it is back to school until it can pass the test. My neural network doesn't have a validation set at the moment, but it seems to work quite well without it. This statement is not entirely true. I tend to validate it using the training data, but maybe in future I will fix it up to use a proper validation set.

So how do you train the neural network ? Back-propagation !

Up Next: Neural Network (Part 5): Back Propagation

To go back to the table of contents click here

ScottC 12 Aug 15:47

arduinobasics best arduino blog code connection layer neural network neuron processing.org programming project tutorial

Neural Network (Part 3): The Layer

The Layer

The purpose of a layer is mainly to group and manage neurons that are functionally similar, and provide a means to effectively control the flow of information through the network (forwards and backwards). The forward pass is when you convert input values into output values, the backwards pass is only done during network training.

In my neural network, the Layer is an essential building block of the neural network. They can work individually or as a team. Let us just focus on one layer for now

This is what a layer with two neurons looks like in my neural network:

As you can see from the picture above, I tend to treat each neuron as an individual.
Both neurons have the same connEntry values (cEn11 = cEn21) and (cEn12 = cEn22), which stem from the layerINPUTs. Other than that, the rest is different. Which means that Neuron1 could produce an output value close to 1, and at the same time Neuron2 could produce an output close to 0, even though they have the same connEntry values at the start.

The following section will describe how the layerINPUTs get converted to actualOUTPUTs.

Step1: Populate the layerINPUTs:
layerINPUTs are just a placeholder for values that have been fed into the neural network, or come from a previous layer within the same neural network. If this is the first layer in the network, then the layerINPUTs would be the Neural Network's input values (eg Sensor data). If this is the 2nd layer in the network, then the layerINPUTs would equal the actualOUTPUTs of Layer One

Step2: Send each layerINPUT to the neuron's connection in the layer.

You will notice that every neuron in the same layer will have the same number of connections. This is because each neuron will connect only once to each of the layerINPUTs. The relationship between layerINPUTs and the connEntry values of a neuron are as follows.

layerINPUTs1:

cEn11 = layerINPUTs1 Neuron1.Connection1.connEntry

cEn21 = layerINPUTs1 Neuron2.Connection1.connEntry

layerINPUTs2:

cEn12 = layerINPUTs2 Neuron1.Connection2.connEntry

cEn22 = layerINPUTs2 Neuron2.Connection2.connEntry

Therefore, the connEntry of the first connection of every neuron in this layer will equal the first layerINPUT value in this layer.

Step3: Calculate the connExit values of each connection (including bias)

           Neuron 1:
           cEx11 = cEn11 x cW11
           cEx12 = cEn12 x cW12
             bEx1 =    1      x    bW1

           Neuron 2:
           cEx21 = cEn21 x cW21
           cEx22 = cEn22 x cW22
             bEx2 =    1      x    bW2

Step4: Calculate the NeuronInputValue for each neuron

          Neuron1:
          Neuron1.NeuronInputValue = cEx11 + cEx12 + bEx1

          Neuron2:
          Neuron2.NeuronInputValue = cEx21 + cEx22 + bEx2

Step5: Send the NeuronInputValues through an Activation function to produce a NeuronOutputValue

          Neuron1:
          Neuron1.NeuronOutputValue= 1/(1+EXP(-1 x Neuron1.NeuronInputValue))

        Neuron2:
          Neuron2.NeuronOutputValue= 1/(1+EXP(-1 x Neuron2.NeuronInputValue))

          Please note that the NeuronInputValues for each neuron are different !

Step6: Send the NeuronOutputValues to the layer's actualOUTPUTs

actualOUTPUT1 = Neuron1.NeuronOutputValue
actualOUTPUT2 = Neuron2.NeuronOutputValue

The NeuronOutputValues become the actualOUTPUTs of this layer, which then become the layerINPUTs of the next layer. And the process is repeated over and over until you reach the final layer, where the actualOUTPUTs become the outputs of the entire neural network.

Here is the code for the Layer class:

processing code Layer Class

01
02
03
04
05
06
07
08
09
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150

class Layer{

  Neuron[] neurons = {};

  float[] layerINPUTs={};

  float[] actualOUTPUTs={};

  float[] expectedOUTPUTs={};

  float layerError;

  float learningRate;

  

  

  /* This is the default constructor for the Layer */

  Layer(int numberConnections, int numberNeurons){

    /* Add all the neurons and actualOUTPUTs to the layer */

    for(int i=0; i<numberNeurons; i++){

      Neuron tempNeuron = new Neuron(numberConnections);

      addNeuron(tempNeuron);

      addActualOUTPUT();

    }

  }

    

  

  /* Function to add an input or output Neuron to this Layer */

  void addNeuron(Neuron xNeuron){

        neurons = (Neuron[]) append(neurons, xNeuron);

  }

  

  

  /* Function to get the number of neurons in this layer */

  int getNeuronCount(){

    return neurons.length;

  }

  

  

  /* Function to increment the size of the actualOUTPUTs array by one. */

  void addActualOUTPUT(){

      actualOUTPUTs = (float[]) expand(actualOUTPUTs,(actualOUTPUTs.length+1));

  }

  

  

  /* Function to set the ENTIRE expectedOUTPUTs array in one go. */

  void setExpectedOUTPUTs(float[] tempExpectedOUTPUTs){

    expectedOUTPUTs=tempExpectedOUTPUTs;

  }

  

  

  /* Function to clear ALL values from the expectedOUTPUTs array */

  void clearExpectedOUTPUT(){

       expectedOUTPUTs = (float[]) expand(expectedOUTPUTs, 0);

  }

  

  

  /* Function to set the learning rate of the layer */

  void setLearningRate(float tempLearningRate){

    learningRate=tempLearningRate;

  }

  

  

  /* Function to set the inputs of this layer */

  void setInputs(float[] tempInputs){

    layerINPUTs=tempInputs;

  }

  

  

  

  /* Function to convert ALL the Neuron input values into Neuron output values in this layer, 

     through a special activation function. */

  void processInputsToOutputs(){

    

    /* neuronCount is used a couple of times in this function. */

    int neuronCount = getNeuronCount();

    

    /* Check to make sure that there are neurons in this layer to process the inputs */

    if(neuronCount>0) {

      /* Check to make sure that the number of inputs matches the number of Neuron Connections. */

      if(layerINPUTs.length!=neurons[0].getConnectionCount()){

        println("Error in Layer: processInputsToOutputs: The number of inputs do NOT match the number of Neuron connections in this layer");

        exit();

      } else {

        /* The number of inputs are fine : continue

           Calculate the actualOUTPUT of each neuron in this layer, 

           based on their layerINPUTs (which were previously calculated).

           Add the value to the layer's actualOUTPUTs array. */

        for(int i=0; i<neuronCount;i++){

          actualOUTPUTs[i]=neurons[i].getNeuronOutput(layerINPUTs);

        }

      }

    }else{

      println("Error in Layer: processInputsToOutputs: There are no Neurons in this layer");

      exit();

    }

  }

  

  

  /* Function to get the error of this layer */

  float getLayerError(){

    return layerError;

  }

  

  

  /* Function to set the error of this layer */

  void setLayerError(float tempLayerError){

    layerError=tempLayerError;

  }

  

  

  /* Function to increase the layerError by a certain amount */

  void increaseLayerErrorBy(float tempLayerError){

    layerError+=tempLayerError;

  }

  

  

  /* Function to calculate and set the deltaError of each neuron in the layer */

  void setDeltaError(float[] expectedOutputData){

    setExpectedOUTPUTs(expectedOutputData);

    int neuronCount = getNeuronCount();

    /* Reset the layer error to 0 before cycling through each neuron */

    setLayerError(0);

     for(int i=0; i<neuronCount;i++){

       neurons[i].deltaError = actualOUTPUTs[i]*(1-actualOUTPUTs[i])*(expectedOUTPUTs[i]-actualOUTPUTs[i]);

       

       /* Increase the layer Error by the absolute difference between the calculated value (actualOUTPUT) and the expected value (expectedOUTPUT). */

       increaseLayerErrorBy(abs(expectedOUTPUTs[i]-actualOUTPUTs[i]));

     }

  }

  

  

  /* Function to train the layer : which uses a training set to adjust the connection weights and biases of the neurons in this layer */

  void trainLayer(float tempLearningRate){

    setLearningRate(tempLearningRate);

    

    int neuronCount = getNeuronCount();

    

    for(int i=0; i<neuronCount;i++){

      /* update the bias for neuron[i] */

      neurons[i].bias += (learningRate * 1 * neurons[i].deltaError);

      

      /* update the weight of each connection for this neuron[i] */

      for(int j=0; j<neurons[i].getConnectionCount(); j++){

          neurons[i].connections[j].weight += (learningRate * neurons[i].connections[j].connEntry * neurons[i].deltaError);

      }   

    }

  }

}

code formatter

Within each layer, you have neuron(s) and their associated connection(s). Therefore it makes sense to have a constructor that automatically sets these up.

If you create a new Layer(2,3), this would automatically

add 3 neurons to the layer
create 2 connections for each neuron in this layer (to connect to the previous layer neurons).
randomise each neuron bias and connection weights.
add 3 actualOUTPUT slots to hold the neuron output values.

Here are the functions of the Layer class:

addNeuron() : adds a neuron to the layer
getNeuronCount() : returns the number of neurons in this layer
addActualOUTPUT() : adds an actualOUTPUT slot to the layer.
setExpectedOUTPUTs() : sets the entire expectedOUTPUTs array in one go.
clearExpectedOUTPUT() : clear all values within the expectedOUTPUTs array.
setLearningRate() : sets the learning rate of the layer.
setInputs() : sets the inputs of the layer.
processInputsToOutputs() : convert all layer input values into output values
getLayerError() : returns the error of this layer
setLayerError() : sets the error of this layer
increaseLayerErrorBy() : increases the layer error by a specified amount.
setDeltaError() : calculate and set the deltaError for each neuron in this layer
trainLayer() : uses a training set to adjust the connection weights and biases of the neurons in this layer

There are a few functions mentioned above, which I have not yet discussed, and are used for neural network training (back-propagation). Don't worry, we'll go through them in the "back-propagation" section of the tutorial.

Next up: Neural Network (Part 4) : The Neural Network class

To go back to the table of contents click here

ScottC 12 Aug 14:58

arduinobasics best arduino blog bias code connection layer neural network neuron processing.org programming project tutorial weight

Neural Network (Part 2) : The Neuron

The Neuron

The main purpose of the Neuron is to store the values that flow through the neural network. They also do a bit of processing through the use of an Activation function. The activation function is quite an important feature of the neural network. It essentially enables the neuron to make decisions (yes/no and greyzone) based on the values provided to them. The other feature of activation functions is the ability to map values of infinite size to a range of 0 to 1. We will be using the Sigmoid function.

The above pictures can be found at Wikipedia

The neuron accumulates signals from one or more connections, adds a bias value, and then sends this value through the activation function to produce a neuron output. Each neuron output will be within the range of 0 to 1 (due to the activation function).

So lets take a look at a single neuron with 2 connections (+ bias) feeding into it.

As seen below.

connEntry weight

Neuron.Connection1.connEntry = cEn1 Neuron.Connection1.weight = cW1

Neuron.Connection2.connEntry = cEn2 Neuron.Connection2.weight = cW2

Neuron.Bias.connEntry = bEn = 1 (always) Neuron.Bias.weight = bW

connExit

Neuron.Connection1.connExit = cEx1

Neuron.Connection2.connExit = cEx2

Neuron.Bias.connExit = bEx

You need to multiply the connEntry value by the weight to get the connExit value.

Connection #1:

cEx1 = cW1 x cEn1

Connection # 2:

cEx2 = cW2 x cEn2

Bias:

bEx = bW x 1

As you can see from the Bias calculation, the Bias.connEntry (bEn) value is always 1, which means that the Bias.connExit (bEx) value is always equal to the Bias.weight (bW) value.

The Neuron Input Value is equal to the sum of all the connExit values (cEx1 and cEx2 in this case) plus the bias (bEx), and can be represented by the following formula.

Neuron Input Value:

Neuron Input Value = cEx1 + cEx2 + bEx

or

Neuron Input Value = [cW1 x cEn1] + [cW2 x cEn2] + [bW x 1]

Now that we have the Neuron Input Value, we can put this through the Activation Function to get the Neuron Output Value. This can be represented by the following formula.

Neuron Output Value:

Neuron Output Value = 1 / (1 + EXP(-1 x Neuron Input Value))

We will use this Neuron Output value as an input to the next layer, therefore it automatically becomes a connEntry for one of the neuron connections in the next layer.

Now that we know what a neuron does, let us create a neuron class. See the code below.

processing code Neuron Class

01
02
03
04
05
06
07
08
09
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

/* ------------------------------------------------------------------------

   A neuron does all the calculations to convert an input to an output

-------------------------------------------------------------------------  */



class Neuron{

  Connection[] connections={};

  float bias;

  float neuronInputValue;

  float neuronOutputValue;

  float deltaError;

  

  //The default constructor for a Neuron

  Neuron(){

  }

  

  //The typical constructor of a Neuron - with random Bias and Connection weights

  Neuron(int numOfConnections){

    randomiseBias();

    for(int i=0; i<numOfConnections; i++){

      Connection conn = new Connection();

      addConnection(conn);

    }

  }

  

  //Function to add a Connection to this neuron

  void addConnection(Connection conn){

      connections = (Connection[]) append(connections, conn);

  }

  

  //Function to return the number of connections associated with this neuron.

  int getConnectionCount(){

      return connections.length;

  }

  

  //Function to set the bias of this Neuron

  void setBias(float tempBias){

    bias = tempBias;

  } 

  

  //Function to randomise the bias of this Neuron

  void randomiseBias(){

    setBias(random(1));

  }

  

  //Function to convert the neuronInputValue to an neuronOutputValue

  //Make sure that the number of connEntryValues matches the number of connections

  

  float getNeuronOutput(float[] connEntryValues){

    if(connEntryValues.length!=getConnectionCount()){

      println("Neuron Error: getNeuronOutput() : Wrong number of connEntryValues");

      exit();

    } 

    

    neuronInputValue=0;

    

    //First SUM all of the weighted connection values (connExit) attached to this neuron. 

    for(int i=0; i<getConnectionCount(); i++){

      neuronInputValue+=connections[i].calcConnExit(connEntryValues[i]);

    }

    

    //Add the bias to the Neuron's inputValue

    neuronInputValue+=bias;

    

    //Send the inputValue through the activation function to produce the Neuron's outputValue

    neuronOutputValue=Activation(neuronInputValue);

    

    //Return the outputValue

    return neuronOutputValue;

  } 

  

  //Sigmoid Activation function

  float Activation(float x){

    float activatedValue = 1 / (1 + exp(-1 * x));

    return activatedValue;

  }

  

}

code formatter

When you create a new Neuron, you have the option to create the basic neuron shell with the Neuron() constructor, however, you are more likely to call the 2nd constructor, which allows you to set the number of input connections attached to this neuron.

For example, if I create a neuron using New Neuron(4), then this will automatically

attach and associate four connections with this neuron
randomise the weight of each connection
randomise the bias of this neuron

These are the functions within the Neuron Class:

addConnection(): adds a new connection to this neuron
getConnectionCount(): returns the number of connections associated with this neuron
setBias(): sets the Bias of the neuron to a specific value.
randomiseBias() : randomises the Bias of this neuron
getNeuronOutput() : values are fed through the neuron's connections to create the neuronInputValue, which is then sent through the Sigmoid Activation function to create the neuronOutputValue.
Activation() : is the function used by the getNeuronOutput() function to generate the neuronOutputValue.

Up next: Neural Network (Part 3) : The Layer

To go back to the table of contents click here

ScottC 11 Aug 17:58

activation function arduinobasics best arduino blog bias code neural network neuron processing.org project sigmoid tutorial weight

Neural Network (Part 1) - The Connection

Introduction

In this tutorial, I am going to walk you through my interpretation of a neural network. I will use terminology that makes sense to me, hoping that Neural Network enthusiasts don't get offended by my novice approach.

This is what a feed-forward Neural network normally looks like:

The input layer receives input from the outside world, and passes this value to the hidden layer.

The value that reaches the hidden layer depends on the connection between the layers.

Each connection has a weight. This weight multiplier can either increase or decrease the value coming from the input layer. Like water coming out of a tap, you can make it come out faster or slower (or not at all). This weight can even be negative, which would mean that the water is being sucked up, rather than pouring out.

The hidden layer then processes the values, and pass them onto the output layer. The connections between the hidden layer and the output layer also have weights. The values in the output layer are processed and produce a final set of results. The final results can be used to make yes/no decisions, or can be used to make certain classifications etc etc. In my case, I would like to receive sensor data from the arduino, pass this info to the neural network, and get it to classify the data into 4 different classes (Red, Yellow, Green or Ambient), but we will get to see this in another tutorial. For now, we are just going to design a neural network that can be applied to any of your arduino projects... so lets start from the ground up.

I have programmed this neural network in the Processing language, and have decided to break the neural network into smaller bits. Each structural component of the neural network is a class (as you will soon discover).

The connection

ConnEntry (x) : is the value being fed into the connection.
Weight (m) : Is the value that either amplifies or weakens the ConnEntry value.
ConnExit (y): Is the output value of the connection.

The relationship between y and x is linear, and can be described by the following formula.

y = mx

In other words, you multiply the ConnEntry value by the Weight to get the ConnExit value.

Here is the code for the Connection class:

processing code Connection Class

01
02
03
04
05
06
07
08
09
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

/* -------------------------------------------------------------------------

A connection determines how much of a signal is passed through to the neuron. 

------------------------------------------------------------------------*/



class Connection{

  float connEntry;

  float weight;

  float connExit;

  

  /*This is the default constructor for a Connection  */

  Connection(){

    randomiseWeight();

  }

  

  /*A custom weight for this Connection constructor  */

  Connection(float tempWeight){

    setWeight(tempWeight);

  }

  

  /*Function to set the weight of this connection  */

  void setWeight(float tempWeight){

    weight=tempWeight;

  }

  

  /*Function to randomise the weight of this connection  */

  void randomiseWeight(){

    setWeight(random(2)-1);

  }

  

 /*Function to calculate and store the output of this Connection  */

  float calcConnExit(float tempInput){

    connEntry = tempInput;

    connExit = connEntry * weight;

    return connExit;

  }

}

code formatter

When a connection class is constructed, it automatically randomises the weight for you.
Here are some of the other functions of this class:

setWeight() : allows you to specifically set the weight of this connection.
randomiseWeight() : can be used to wipe the "memory" of the connection if required.
calcConnExit() function is the main function of this class. It is the one that multiplies the connEntry value with the Weight to produce a connExit value as described above.

Up next: Neural Network (Part 2): The Neuron

-------------------------------------------------------------------------

To go back to the table of contents click here

ScottC 11 Aug 16:16

arduinobasics best arduino blog code connection feed forward neural network processing.org project tutorial weight

ArduinoMania

Updates

Search

Add blog

Tags

Posts with «processing.org» label

Jumper: Arduino controlled animation

The Project Movie

Components Required

The Arduino Sketch

The Arduino Code:

The Processing Code:

The pictures

Neural Network (Part 7) : Cut and Paste Code

Processing sketch

Neural Network (Part 6) : Back Propagation, a worked example

Neural Network (Part 5): The Back Propagation process

Neural Network (Part 4): The Neural Network class

processing code Neural Network Class

Neural Network (Part 3): The Layer

processing code Layer Class

Neural Network (Part 2) : The Neuron

processing code Neuron Class

Neural Network (Part 1) - The Connection

processing code Connection Class